PC Answers 1998 January/PC Answers Issue 49 Cover CD January 1998.iso/Apps/Director/DATA.Z/Lists Lingo.dir/Scripts_4_More List Handlers.ls

Text File | 1997-05-10 | 1.7 KB | 47 lines

on FindHelpSprites
  global gMaxChannels, gHelpSpritesList, gRolloverButtons
  set gHelpSpritesList to [:]
  set gRolloverButtons to [:]
  repeat with N = 1 to gMaxChannels
    if the type of sprite N <> 0 then
      set vMemberName to the name of the member of sprite N
      if vMemberName contains "Help" then
        setaProp(gHelpSpritesList, N, the number of the member of sprite N)
      end if
      if vMemberName contains "Round Button" then
        setaProp(gRolloverButtons, N, the name of the member of sprite N)
      end if
    end if
  end repeat
end

on doHelpCheck
  global gMaxChannels, gHelpSpritesList, gRolloverButtons
  if not (the mouseDown) and (the mouseCast > 0) then
    set vButtonOrderNumber to 0
    repeat with N = 1 to count(gRolloverButtons)
      set vCurrentSprite to getPropAt(gRolloverButtons, N)
      if rollOver(vCurrentSprite) then
        set vButtonOrderNumber to N
      end if
    end repeat
    if vButtonOrderNumber > 0 then
      repeat with m in gHelpSpritesList
        if the name of cast m contains "Help Text" then
          set vFirstTextMemberNumber to m
          set vFirstTextMemberName to m
          set vTextSprite to getOne(gHelpSpritesList, m)
        end if
        if the name of cast m contains "help line" then
          set vFirstLineMemberNumber to m
          set vLineSprite to getOne(gHelpSpritesList, m)
        end if
      end repeat
      puppetSprite(vTextSprite, 1)
      set the memberNum of sprite vTextSprite to vFirstTextMemberNumber + vButtonOrderNumber - 1
      puppetSprite(vLineSprite, 1)
      set the memberNum of sprite vLineSprite to vFirstLineMemberNumber + vButtonOrderNumber - 1
    end if
  end if
end